Финансово – Технологическая Академия

Колледж Космического Машиностроения и Технологии

Дисциплина: «Инструментальные средства разработки»

Лабораторный практикум по языку VBA

Составитель

Гусятинер Л.Б.

Королев

2014

Оглавление

[Лабораторная работа №1. Введение в VBA. Ветвление 3](#_Toc414959105)

[Лабораторная работа №2. Select..Case. Операции с целыми числами: mod, \ 5](#_Toc414959106)

[Лабораторная работа №3. Типы данных и операции 8](#_Toc414959107)

[Лабораторная работа №4. Циклы 12](#_Toc414959108)

[Лабораторная работа №5. Функции и процедуры 16](#_Toc414959109)

[Лабораторная работа №6. Массивы 23](#_Toc414959110)

[Лабораторная работа № 9. Структурные типы данных. Записи. 26](#_Toc414959111)

[Лабораторная работа №11-12. Объекты 29](#_Toc414959112)

[Контрольная работа 37](#_Toc414959113)

# Лабораторная работа №1. Введение в VBA. Ветвление

**Цель работы:** знакомство со средой разработки Excel – VBA и выполнение простейших программ.

**Необходимые предварительные знания:**

1. Структура простейшей программы. Sub и End Sub
2. Переменные. Имена. Объявление Dim. Тип Integer
3. Среда Excel
4. Ввод InputBox и вывод Debug.Print
5. Ветвление. It..Else If..Else..End If
6. Комментарии.

**Ход работы:**

1. Запустить Excel.
2. Перейти в режим: Сервис->Макрос->Безопасность. Установить уровень не выше среднего.
3. Перейти в режим: Сервис->Макрос->Редактор Visual Basic. Установить режим отладочной печати (Immediate window). Добавить модуль Insert->Module. Переименовать его как Примеры.
4. Рассмотреть примеры программ из настоящей работы, скопировать их в созданный модуль, запустить.
5. Выполнить задания.

Sub p01()

' Сумма двух чисел

Dim a As Integer, b As Integer, с As Integer

' Объявление переменных с именами a, b, с и типом Integer

a = InputBox("Введите а")

b = InputBox("Введите b ")

с = a + b 'Складываем значения переменных a и b и результат заносим переменную (ячейку) с

' результат заносим в ячейку sum

MsgBox (с)

End Sub

Sub p02()

' Абсолютная величина числа

Dim x As Integer, y As Integer

x = InputBox("Введите число")

If x >= 0 Then y =x Else y = -x

MsgBox y

End Sub

Sub p03()

' Наибольшее из трех чисел

' Вариант 1

Dim a As Integer, b As Integer, c As Integer, max As Integer

a = InputBox("Первое число")

b = InputBox("Второе число")

c = InputBox("Третье число")

If (a > b) And (a > c) Then

max = a

ElseIf (b > a) And (b > c) Then

max = b

Else

max = c

End If

MsgBox max

End Sub

Sub p04()

' Наибольшее из трех чисел

' Вариант 2

Dim a As Integer, b As Integer, c As Integer, max As Integer

a = InputBox("Первое число")

b = InputBox("Второе число")

c = InputBox("Третье число")

max = a

If b > max Then max = b

If c > max Then max = c

MsgBox max

End Sub

**Задания для самостоятельной работы**

1. Наибольшее из четырех чисел
2. Сколько корней имеет квадратное уравнение a\*x^2+b\*x+c=0
3. Название дня недели по его номеру
4. Количество уроков по номеру дня недели
5. Название месяца по его номеру
6. Количество дней в месяце по номеру (год - невисокосный)

**Содержание отчета:**

* Тексты заданий
* Тексты программ

# Лабораторная работа №2. Select..Case. Операции с целыми числами: mod, \

**Задание 1.** По цвету светофора определить действия пешехода.

Версия с использованием IF

Sub p21()

' Светофор

Dim цвет As String 'цепочка символов переменной длины

' может быть нулевой длины, то есть не содержащей ни одного символа

Dim указание As String \* 20 'или 20 байт

цвет = InputBox("Какой цвет у светофора?")

if цвет = "красный" then

указание = "стойте"

elseif цвет = "желтый" then

указание = "ждите"

elseif цвет = "зеленый" then

указание = "идите"

Else

указание = "светофор неисправен"

End Select

MsgBox (указание)

End Sub

Теперь версия с использованием Select..Case

Sub p22()

' Светофор

Dim цвет As String 'цепочка символов переменной длины

' может быть нулевой длины, то есть не содержащей ни одного символа

Dim указание As String \* 20 'или 20 байт

цвет = InputBox("Какой цвет у светофора?")

Select Case цвет

Case "красный"

указание = "стойте"

Case "желтый"

указание = "ждите"

Case "зеленый"

указание = "идите"

Case Else

указание = "светофор неисправен"

End Select

MsgBox (указание)

End Sub

Задание: введено слово "Красный". Что выдаст программа?, почему?

Определить число дней в месяце (год невисокосный)

Sub p23()

'Количество дней в месяце, год - невисокосный

Dim мес As Integer, дни As Integer

' вводим номер месяца и присваиваем его переменной мес

мес = InputBox("Введите № месяца")

' анализируем переменную (содержимое ячейки) мес

If (мес = 1) or (мес = 3) or (мес = 5) or (мес = 7) or (мес = 8 ) or (мес=10)

дни = 31

elseif (мес = 4) or (мес = 6) or (мес = 9) or (мес = 11 )

дни = 30

elseif (мес=2) then

дни = 28

Else

дни = -1 'ввод ошибочного значения

Endif

' если дни=-1, считаем ошибкой

If дни > 0 Then

MsgBox (дни)

Else

MsgBox ("ошибка, неверный ввод!")

End If

Sub p24()

'Количество дней в месяце, год - невисокосный

Dim мес As Integer, дни As Integer

' вводим номер месяца и присваиваем его переменной мес

мес = InputBox("Введите № месяца")

' анализируем переменную (содержимое ячейки) мес

Select Case мес

Case 1, 3, 5, 7, 8, 10, 12

дни = 31

Case 4, 6, 9, 11

дни = 30

Case 2

дни = 28

Case Else

дни = -1 'ввод ошибочного значения

End Select

' если дни=-1, считаем ошибкой

If дни > 0 Then

MsgBox (дни)

Else

MsgBox ("ошибка, неверный ввод!")

End If

End Sub

**Задания для самостоятельной работы:**

Программа запрашивает у студента баллы, полученные на экзамене по информатике и печатает: «отлично», «хорошо», «удовлетворительно», «неудовлетворительно»

Программа запрашивает оценки у студента по всем предметам в сессию и печатает средний балл, а также: «отлично», «хорошо», «удовлетворительно», «неудовлетворительно»

Программа запрашивает у студента процент выполнения заданий на экзамене и печатает: от 90 до 100 - «отлично», не менее 80 - «хорошо», не менее 60 - «удовлетворительно», меньше 60 (но не меньше нуля) - «неудовлетворительно», во всех остальных случаях – ошибка.

Программа запрашивает у студента номер дня и выдает количество уроков

**Содержание отчета:**

* Тексты заданий
* Тексты программ

# Лабораторная работа №3. Типы данных и операции

**Таблица 1. Типы данных в VBA**

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| Название типа | Содержимое | Память,  байт | Диапазон  возможных  значений | Префикс | Операции |
| Integer | Целые числа | 2 | [-215;215-1] | Int |  |
| Long | Целые числа | 4 | [-231;231-1] | Lng |  |
| Single | Вещественные числа  одинарной точности | 4 | [-2128;-2-1074] и  [-2-1074;21024-1] | Sng |  |
| Double | Вещественные числа  двойной точности | 8 | [-21024;-2-149] и  [-2-149;2128-1] | Dbl |  |
| Currency | Вещественные числа  (целая часть – до 15  цифр, дробная часть –  до 4 цифр) | 8 | [-263⋅10-4;(-263-1)⋅10-4] | Cur |  |
| String | Текст | 1 для каждого  символа | До 216 символов для  строк фиксированной  длины  До 231 символов  для динамических строк | Str |  |
| Byte | Целые числа | 1 | [0;28-1] | Byt |  |
| Boolean | Логические значения | 2 | [True, False] | Bln |  |
| Date | Дата и время | 8 | [1.01.100;31.12.9999] | Dtm |  |
| Object | Объект | 4 | Ссылка на объект | Obj |  |
| Variant | Любая | 16+  (1 для каждого  символа) | Диапазон не определен | Vnt |  |

Образец объявления в программе.

Dim переменная [As тип]

Для повышения информативности используемых имен переменных и констант программисты используют в именах префиксы, указывающие на тип.

Примеры:

Dim intПервая, intВторая, intСумма as Integer

Dim blnНайдено as Boolean, blnЗавершено as Boolean

Dim strFirstName, strLastName, strMidName as string \*20

**Задание 1.** Заполнить столбец операций в таблице 1

**Задание 2.** Обучающая программа.

I. Выдать список всех типов данных из таблицы 1, используя msgBox, например,

Integer

Long

Byte

Currency

String и так далее.

II. Прочитать число, используя inputBox.

III. По введенному номеру типа выдать нумерованный список допустимых для данного типа операций, например,

Сложение a+b

Умножение a\*b …

Если число не совпадает с 1.. 11, выдать сообщение об ошибке и завершить работу.

IV. Запросить номер операции.

V. По введенному номеру запросить операнды (один или два). Если номер не совпадает ни с одним из указанных номеров операций, выдать сообщение об ошибке и завершить работу.

VI. Выдать результат операции

Последовательность работы над программой

Воспользуемся блокнотом

Дадим имя программе

Напишем сценарий из пунктов задания.

Начнем последовательно детализировать каждый пункт. Необходимо соблюдать правило: в любой момент создания программа должна быть рабочей. Если пока неясно, как реализовать какое-то действие на языке VBA, ставим «заглушку», например, выдачу сообщения «Пункт не работает». Для получения значений промежуточных переменных используем отладочную печать.

**Этап 1**

‘В начале файла (или модуля, если текст набирается во встроенном редакторе VBA), напишем фразу

Option Explicit

‘ В этом случае транслятор находит ошибки, если данные (переменные или константы) не описаны

Sub ТипыДанных()

‘I. Выдать список всех типов данных, используя msgBox.

‘II. Прочитать число, используя inputBox.

‘III. По введенному номеру типа выдать нумерованный список допустимых для данного типа операций. ‘Если число не совпадает с 1.. 11, выдать сообщение об ошибке.

‘IV. Запросить номер операции.

‘V. По введенному номеру запросить операнды (один или два). Если номер не совпадает ни с одним из ‘указанных номеров операций, выдать сообщение об ошибке.

‘VI. Выдать результат операции

End sub

**Этап 2**

Sub ТипыДанных()

‘I. Выдать список всех типов данных, используя msgBox.

Dim strМеню1 as string

‘ Сформируем набор строк. Для перехода на следующую строку используем константу vbNewLine

StrМеню1 = “”

StМеню1 = strМеню1+”Чтобы выбрать тип данных, введите его номер”+vbNewLine

StrМеню1 = StrМеню1+ “1.Integer”+vbNewLine

StrМеню1 = StrМеню1+ “2.Long ”+vbNewLine ‘ и так далее

MsgBox (StrМеню1)

‘II. Прочитать число, используя inputBox.

‘III. По введенному номеру типа выдать нумерованный список допустимых для данного типа операций. ‘Если число не совпадает с 1.. 11, выдать сообщение об ошибке.

‘IV. Запросить номер операции.

‘V. По введенному номеру запросить операнды (один или два). Если номер не совпадает ни с одним из ‘указанных номеров операций, выдать сообщение об ошибке.

‘VI. Выдать результат операции

End sub

**Этап 3**

Sub ТипыДанных()

Dim strМеню1 as string ‘ Строки сообщения, содержащие список типов

Dim НомерТипа as Integer ‘ Номер типа данных из списка

‘I. Выдать список всех типов данных, используя msgBox.

‘ Сформируем набор строк. Для перехода на следующую строку используем константу vbNewLine

StrМеню1 = “”

StМеню1 = strМеню1+”Чтобы выбрать тип данных, введите его номер”+vbNewLine

StrМеню1 = StrМеню1+ “1.Integer”+vbNewLine

StrМеню1 = StrМеню1+ “2.Long”+vbNewLine ‘ и так далее

MsgBox (StrМеню1)

‘II. Прочитать число, используя inputBox.

НомерТипа = inputBox(“”)

‘III. По введенному номеру типа выдать нумерованный список допустимых для данного типа операций. ‘Если число не совпадает с 1.. 11, выдать сообщение об ошибке.

‘IV. Запросить номер операции.

‘V. По введенному номеру запросить операнды (один или два). Если номер не совпадает ни с одним из ‘указанных номеров операций, выдать сообщение об ошибке.

‘VI. Выдать результат операции

End sub

**Этап 4**

Sub ТипыДанных()

Dim strМеню1 as string ‘ Строки сообщения, содержащие список типов

Dim НомерТипа as Integer ‘ Номер типа данных из списка

Dim НомерОперации as Integer ‘ Номер операции

‘I. Выдать список всех типов данных, используя msgBox.

‘ Сформируем набор строк. Для перехода на следующую строку используем константу vbNewLine

StrМеню1 = “”

StrМеню1 = StrМеню1+ ”Чтобы выбрать тип данных, введите его номер” + vbNewLine

StrМеню1 = StrМеню1+ “1.Integer”+ vbNewLine

StrМеню1 = StrМеню1+ “2.Long ”+vbNewLine ‘ и так далее

MsgBox (StrМеню1)

‘II. Прочитать число, используя inputBox.

НомерТипа = inputBox(“”)

‘III. По введенному номеру типа выдать нумерованный список допустимых для данного типа операций. ‘Если число не совпадает с 1.. 11, выдать сообщение об ошибке.

StrМеню2 = “”

Select case НомерТипа

Case 1

StrМеню2 = StrМеню2 + “Тип Integer” +vbNewLine

StrМеню2 = StrМеню2 + “1.Сложение a+b”+vbNewLine

StrМеню2 = StrМеню2 + “2.Умножение a\*b”+vbNewLine

‘ и так далее

Case 2

StrМеню2 = StrМеню2 + “Тип Long ” +vbNewLine

StrМеню2 = StrМеню2 + “1.Сложение a+b”+vbNewLine

Case else

MsgBox (“Ошибка. Номер введен неверно”)

Exit sub ‘ Немедленный выход из программы

End select

‘IV. Запросить номер операции.

НомерОперации = inputBox(“”)

‘V. По введенному номеру запросить операнды (один или два). Если номер не совпадает ни с одним из ‘указанных номеров операций, выдать сообщение об ошибке.

‘VI. Выдать результат операции

End sub

**Задание 3.** Таблица истинности

Напечатать список логических операций

Прочитать номер операции

По введенному номеру выдается таблица истинности для данной операции (с заголовком таблицы). Если введен номер 99, выводится сводная таблица истинности. Если вводится номер, отличный от номеров элементов списка и 99, выдается сообщение об ошибке и работа завершается.

Содержание отчета:

Заполненная таблица операций

Сводная таблица истинности

Тексты заданий

Тексты программ

# Лабораторная работа №4. Циклы

Циклом называется повторяющаяся последовательность действий. Например,

Сделать 10 шагов означает:

10 раз сделать шаг

Съесть 5 конфет означает:

5 раз съесть конфету

Дойти до стены означает:

Пока впереди нет стены идти

Прочитать книгу означает:

Пока не закончатся страницы

читать страницу

перелистать страницу

Как мы видим, циклы бывают двух видов: с известным числом повторений (примеры 1 и 2) и с неизвестным числом повторений (примеры 3 и 4). Рассмотрим сначала циклы, в которых действия повторяются заранее заданное количество раз. Чтобы сделать 10 шагов, нужно как-то эти шаги отмечать: записывать, откладывать на счетах, загибать пальцы, считать вслух или «про себя». Короче, нужен счетчик. Теперь можем наш первый пример записать так:

10 раз сделать шаг, или:

for счетчик = 1 to 10

СделатьШаг

next

Положить 5 рублей в копилку означает: 5 раз положить 1 рубль в копилку или

for k=1 to 5

ПоложитьРубльВкопилку

next

Какая сумма будет в копилке, если сначала копилка была пуста?

Считать копилку пустой

For k=1 to 5

Положить 1 рубль в копилку

Next

Немного изменим инструкции:

Пусть содержимое копилки равно нулю

For k=1 to 5

Прибавить к содержимому копилки 1 рубль

Next

Посмотреть, что в копилке

Последняя фраза, как следует из условия задачи, выполняется один раз после завершения 5 дней, то есть после завершения цикла из 5 повторений. Наконец, VBA:

копилка = 0

for k =1 to 5

копилка = копилка + 1

next

MsgBox копилка

Построим таблицу, из которой видно, как растет наше состояние.

Таблица 1.

|  |  |  |
| --- | --- | --- |
| Дни | Положили | Стало |
| 0 | - | 0 |
| 1 | 1 | 1 |
| 2 | 1 | 2 |
| 3 | 1 | 3 |
| 4 | 1 | 4 |
| 5 | 1 | 5 |

Такая таблица называется трассировочной.

Если процесс описан в терминах языка программирования, таблица преобразуется в табл.2

Таблица 2.

|  |  |
| --- | --- |
| K | Копилка |
| ? | 0 |
| 1 | 1 |
| 2 | 2 |
| 3 | 3 |
| 4 | 4 |
| 5 | 5 |

Изменим задачу. Пусть в 1й день положили 1 рубль, во 2й – 2 рубля, в 3й – 3 рубля, …, то есть в день с номером k положили k рублей. Тогда изменим программу:

копилка = 0

for k=1 to 5

копилка = копилка + k

next

MsgBox копилка

Таблица 3.

|  |  |
| --- | --- |
| K | Копилка |
| ? | 0 |
| 1 | 1 |
| 2 | 1+2=3 |
| 3 | 3+3=6 |
| 4 | 6+4=10 |
| 5 | 10+5=15 |

В абстрактной (математической) форме эта задача звучит так: найти сумму первых натуральных чисел от 1 до 5. Вместо переменной копилка удобней использовать переменную сумма

сумма = 0

for k=1 to 5

сумма = сумма + k

next

MsgBox сумма

Найти произведение первых пяти натуральных чисел (от 1 до 5). Чтобы решить задачу, нужно вспомнить, что роль нуля в умножении играет единица, то есть число⋅1 = 1⋅число = число для любого числа.

Следовательно, в программе про сумму остается заменить 0 на 1, «+» на «\*», и поменять обозначения, вместо «сумма» использовать «произв». Получим

Произв = 1

for k=1 to 5

произв = произв⋅k

next

MsgBox произв Циклы с неизвестным заранее числом повторений.

‘Do While (пока не стена )

‘ СделатьШаг

‘Loop

‘ Положить 5 рублей в копилку

Копилка = 0

Дни = 1

Do while (Дни < =5)

Копилка = копилка + 1

Дни = дни + 1

Loop

Задание Выполнить задачи и упражнения из раздела 4 по номеру своего варианта

Содержание отчета:

Тексты заданий

Тексты программ

# Лабораторная работа №5. Функции и процедуры

Цель работы: развитие техники использования функций и процедур. Статические и динамические переменные.

Необходимые предварительные знания:

типы данных, функции преобразования, функции определения типа

статически и динамические переменные

передача параметров по ссылке и по значению

побочный эффект

рекурсия

Ход работы. Рассмотреть примеры использования процедур и функций, скопировать их в редактор VBA, запустить, выполнить задания.

Примеры

‘ 1. Процедуры

Option Explicit

Sub ТестПоЗначениюПоСсылке()

' Тест передачи параметров по значению (by value)

' и по ссылке (by reference)

Dim a As Integer

a = 5

MsgBox "До вызова процедуры замены a=" & a

Call ДурнаяЗамена(a)

MsgBox "После вызова процедуры замены a=" & a

Call Замена(a)

MsgBox "После вызова процедуры замены a=" & a

End Sub

Sub ДурнаяЗамена(ByVal a As Integer)

a = 4

MsgBox "Внутри процедуры замены a=" & a

End Sub

Sub Замена(ByRef a As Integer)

a = 4

MsgBox "Внутри процедуры замены a=" & a

End Sub

Sub ГлупыйМакс(ByVal a As Integer, ByVal b As Integer)

Dim наибольшее As Integer

If a > b Then наибольшее = a Else наибольшее = b

MsgBox "наибольшее=" & наибольшее

End Sub

Sub ВерныйМакс1(ByVal a As Integer, ByVal b As Integer, ByRef c As Integer)

If a > b Then c = a Else c = b

MsgBox "Внутри ВерныйМакс=" & c

End Sub

Function ВерныйМакс2(ByVal a As Integer, ByVal b As Integer) As Integer

If a > b Then ВерныйМакс2 = a Else ВерныйМакс2 = b

MsgBox "Внутри ВерныйМакс=" & ВерныйМакс2

End Function

‘ 2. Функции

2.1 Работа с типами Integer, Double

Function CуммаЦел(ByVal a As Integer, ByVal b As Integer) As Integer

' сумма двух целых переменных

СуммаЦел = a + b

End Function

Function СуммаВещ(ByVal a As Double, ByVal b As Double) As Double

' сумма двух вещественных переменных

СуммаВещ = a + b

End Function

2.2 Работа с типами Boolean

Option Explicit

Function И(ByVal a As Boolean, ByVal b As Boolean) As Boolean

И = a And b

End Function

Function ЕСЛИ(a As Boolean, b As Boolean) As Boolean

ЕСЛИ = a Imp b

End Function

2.3 пользовательскими типами

Option Explicit

Type Complex

Re As Double

Im As Double

End Type

Function СуммаКомпл(ByRef z1 As Complex, ByRef z2 As Complex) As Complex

СуммаКомпл.Re = z1.Re + z2.Re

СуммаКомпл.Im = z1.Im + z2.Im

End Function

2.4 Тест функций

Sub ТестАрифметика()

' Тест Функций для работы с типами Integer, Double

' и пользовательскими типами

Dim i1 As Integer, i2 As Integer, i3 As Integer

Dim d1 As Double, d2 As Double, d3 As Double

Dim z1 As Complex, z2 As Complex, z3 As Complex

i1 = 2

i2 = 3

d1 = 1.5

d2 = 2.5

With z1

.Re = 1.1

.Im = 1.2

End With

With z2

.Re = 2.1

.Im = 2.2

End With

i3 = СуммаЦел(i1, i2)

d3 = СуммаВещ(d1, d2)

z3 = СуммаКомпл(z1, z2)

MsgBox "1.Арифметические операции " & vbNewLine & \_

"СуммаЦел " & i1 & "+" & i2 & "=" & i3 & vbNewLine & \_

"СуммаВещ " & d1 & "+" & d2 & "=" & d3 & vbNewLine & \_

"СуммаКомпл " & \_

ComplToStr(z1) & "+" & ComplToSt(z2) & "=" & ComplToStr(z3)

End Sub

Sub ТестЛогика()

MsgBox И(False, True)

MsgBox ЕСЛИ(2 \* 2 = 5, 3 \* 3 = 6)

End Sub

Sub ТестВидимости()

Dim a As Integer, b As Integer

a = 5

b = 3

MsgBox "Вызов ВерныйМакс=" & ВерныйМакс(a, b)

Call ГлупыйМакс(a, b)

' MsgBox наибольшее

End Sub

2.5 Работа с массивами

Option Explicit

Sub ТестМаксЭлем()

' Тест функций для обработки массивов

Const размер As Integer = 5

Dim массив(размер) As Integer

Dim i As Integer

' инициализация

For i = 0 To размер

массив(i) = Rnd \* 100

Debug.Print массив(i)

Next

MsgBox МаксЭлем(массив)

End Sub

Option Explicit

Function МаксЭлем(ar() As Integer) As Integer

Dim i As Integer

МаксЭлем = -9999

For i = 0 To UBound(ar)

If ar(i) > МаксЭлем Then МаксЭлем = ar(i)

Next

End Function

2.6 Статические переменные

Option Explicit

Sub test()

' Тест статической переменной

Dim i As Integer

For i = 1 To 3

Call pp

Next

End Sub

Sub pp()

' Статическая s1 и динамическая s2 переменные

Static s1 As String

Dim s2 As String

s1 = s1 + "\*"

s2 = s2 + "+"

MsgBox s1 + " " + s2

End Sub

Задания

Написать функции для типов Integer, Double и Complex

Function ПроизведениеЦел(byVal i1 As Integer, byVal i2 as integer) as integer

End Function

Function РазностьЦел(??) as ??

End Function

Function ЧастноеЦел(??) as ??

End Function

…

Function РазностьКомпл(ByRef z1 As Complex, ByRef z2 As Complex) As Complex

End Function

Function ПроизведениеКомпл()

End Function

Function ЧастноеКомпл()

End Function

Function Модуль(ByRef z As Complex) As Double

End Function

Function Вещ(Byref z As Complex) As Double

End Function

Function Мним() As Double

End Function

Function ComplToStr(z As Complex) As String

toString = "" & z.Re & "+" & z.Im & "i"

End Function

Написать функции для типа Boolean

Function ИЛИ()

End Function

Function ВЛЕЧЕТ()

End Function

Function НЕ(ByVal a As Boolean) As Boolean

End Function

Function ЭКВИВАЛЕНТНО()

End Function

Написать функции для обработки массивов

Function МинЭлем(мас() As Integer) As Integer

End Function

Function Среднее(мас() As Integer) As Integer

End Function

Function Мода()

' наиболее часто встречающееся

End Function

Дана точка с координатами x, y. Написать процедуры (1 – 6) :

Move(byRef x, byRef y as integer, byVal OffsetX, OffsetY as \_ integer)

Down (byRef x as integer, byVal OffsetX)

Left (??) as ??

Right (??) as ??

Get(?? ??) ‘ чтение координат inputbox

Show(?? ??) ‘ печать координат

Написать функцию Distance (x1 as integer, y1 as integer, x2 as integer \_ , y2 as integer) as double

Написать процедуру Обход. В цикле вводятся пары координат фигуры, которую нужно обойти, используя процедуры (1 – 6)

рекурсивным методом

при помощи статической переменной

Содержание отчета

Тексты заданий

Тексты программ

Названия каталогов и файлов с программами

# Лабораторная работа №6. Массивы

Цель работы: развитие техники использования функций и процедур. Статические и динамические переменные.

Необходимые предварительные знания:

Циклы

Функции и процедуры

Статические и динамические массивы. Способы объявления массивов. Функции LBound и Ubound. Передача массива в функцию (процедуру) и возврат массива из функции.

Ход работы. Рассмотреть примеры работы с массивами, скопировать их в редактор VBA, запустить, выполнить задания.

Примеры

Статические массивы

Option Explicit

Sub p01()

' Статические одномерный и двумерный массивы

Const Размер As Integer = 4

Const m As Integer = 3

Const n As Integer = 4

Dim i As Integer, j As Integer

Dim arr(Размер) As Integer ' Массив содержит Размер+1 элементов

Dim arr2X(1 To m, 1 To n) As Boolean ' Массив содержит m \* n элементов

Dim s1 As String, s2 As String

' Заполнение одномерного массива случайными числами в интервале 0..1

For i = 0 To Размер

arr(i) = CInt(Rnd)

Next

' Заполнение двумерного массива логическими значениями

i = 0

Do While i < m

i = i + 1

j = 0

Do While j < n

j = j + 1

arr2X(i, j) = ((i + j) Mod 2 = 0)

Loop

Loop

s1 = "Одномерный массив" & vbNewLine

For i = LBound(arr) To UBound(arr)

s1 = s1 & " " & arr(i)

Next

s2 = "Двумерный массив" & vbNewLine

i = LBound(arr2X, 1)

Do While i <= UBound(arr2X, 1)

j = LBound(arr2X, 2)

Do While j <= UBound(arr2X, 2)

s2 = s2 & " " & arr2X(i, j)

If j Mod 4 = 0 Then s2 = s2 & vbNewLine

j = j + 1

Loop

i = i + 1

Loop

MsgBox s1 & vbNewLine & s2

End Sub

Динамические массивы

Sub p02()

' Динамический массив

Dim i As Integer, j As Integer, s As String

Dim arr() As Integer

s = "Одномерный массив" & vbNewLine

ReDim arr(InputBox("lo=") To InputBox("hi="))

For i = LBound(arr, 1) To UBound(arr, 1)

arr(i) = CInt(Rnd)

s = s & arr(i)

Next

s = s & vbNewLine & "Двумерный массив" & vbNewLine

ReDim arr(InputBox("lo\_1=") To InputBox("hi\_1="), \_

InputBox("lo\_2=") To InputBox("hi\_2="))

i = LBound(arr, 1)

Do While i <= UBound(arr, 1)

j = LBound(arr, 2)

Do While j <= UBound(arr, 2)

arr(i, j) = CInt(Rnd)

s = s & arr(i, j)

j = j + 1

Loop

s = s & vbNewLine

i = i + 1

Loop

MsgBox s

End Sub

Задания

Контрольные вопросы

Дан массив arr (5,5). Сколько элементов он содержит?

Дан массив arr(1 to 2, 3 to 4, 5 to 6). Чему раното выдаст lbound(arr,3)?

Программы

Найти сумму (произведение) положительных (отрицательных) элементов двумерного массива, используя структуры do while .. loop и for .. next.

Найти наибольший (наименьший) элемент одномерного массива

Дан массив 8\*8 типа Integer, представляющий шахматную доску. Даны координаты фигуры на этой доске. Какие поля находятся под боем этой фигуры, если это король (ферзь, ладья, конь, слон, пешка). Подсчитать количество полей. Список полей и количество вывести при помощи MsgBox.

Даны две матрицы. Найти их сумму (произведение). Если это невозможно, выдать сообщение об ошибке.

Выполнить задание из задачника (раздел 6) по номеру своего варианта (последняя цифра зачетки).

Содержание отчета

Тексты заданий

Тексты программ

Названия каталогов и файлов с программами

# Лабораторная работа № 9. Структурные типы данных. Записи.

Цель работы: развитие техники использования структурных типов данных. Создание и обработка записей, массивов записей. Инструкция присоединения With

Необходимые предварительные знания:

комплексные числа, модуль, сумма, разность, произведение, частное

циклы, функции, процедуры, массивы, записи

Ход работы. Рассмотреть примеры использования массивов и записей, скопировать их в редактор VBA, запустить, выполнить задания.

Примеры

‘ 1. Тип комплексное число

Option Explicit

Type complex

re As Double ‘ действительная часть

im As Double ‘ мнимая часть

End Type

Function модуль(byVal c As complex) as complex

модуль = Math.Sqr(c.re ^ 2 + c.im ^ 2)

End Function

Sub main()

Dim c1 As complex, c2 As complex

c1.re = InputBox("")

c1.im = InputBox("")

With c2

.re = InputBox("")

.im = InputBox("")

End With

MsgBox "c1->" & модуль(c1) & vbNewLine & "c2->" & модуль(c2)

End Sub

‘ 2. Типы Папа, Сын, Внук

‘ Папа – фамилия

‘ Сын – фамилия + отчество

‘ Внук – фамилия + отчество + имя

Public Type papa

LastName As String

End Type

Public Type son

p As papa

MidName As String

End Type

Public Type gSon

s As son

FirstName As String

End Type

Sub Family()

Dim gs As gSon, st As String

st = ""

With gs

.FirstName = "Иван"

With .s

.MidName = "Иванович"

With .p

.LastName = "Иванов"

End With

End With

End With

With gs

st = st + .FirstName + " " + .s.MidName + " " + .s.p.LastName

End With

MsgBox st

End Sub

'3. Массивы записей

Option Explicit

Sub read\_arr\_complex(ByVal asize As Integer, ByRef arr() As complex)

' Ввод массива комплексных чисел

Dim i As Integer

ReDim arr(asize - 1)

For i = 0 To asize - 1

arr(i).re = InputBox("")

arr(i).im = InputBox("")

Next

End Sub

Sub print\_arr\_complex(ByRef arr() As complex)

' Печать массива комплексных чисел

Dim i As Integer

Dim ans As String, c As String

ans = ""

For i = LBound(arr) To UBound(arr)

c = arr(i).re & IIf(arr(i).im > 0, "+", "") & arr(i).im & "i"

ans = ans & c & vbNewLine

Next

MsgBox ans

End Sub

Sub main() ‘ для проверки

Const n As Integer = 3

Dim arr() As complex

ReDim arr(n - 1)

read\_arr\_complex n, arr

print\_arr\_complex arr

End Sub

Задания

Описать функции для типа complex

Function сумма(c1 As complex, c2 As complex) As complex

End Function

Function произведение(c1 As complex, c2 As complex) As complex

End Function

Function разность()

End Function

Function частное()

End Function

Описать типы man, student, teacher. Описать функции show (печать информации) для каждого типа. В описание каждого из типов student и teacher включить переменную типа man

Type man

End Type

Type student

End Type

Type teacher

End Type

Написать программу для ввода и печати массива студентов

Содержание отчета

Тексты заданий

Тексты программ

Названия каталогов и файлов с программами

# Лабораторная работа №11-12. Объекты

Цель работы: знакомство с объектами и основами объектно-ориентированного программирования в VBA

Необходимые предварительные знания:

2.1 Циклы

2.2 Функции

Ход работы:

Рассмотреть примеры описания классов и создания объектов, файлы:

Студент.xls

Вектор.xls

Зоопарк.xls

Выполнить задания:

Дополнить зоопарк животными на усмотрение студента ( не менее двух )

Создать класс Время, написать методы:

toString возвращает строку, подобно “02:10:15”

Вычесть (2часа 10мин 15сек – 55 минут) => 1час 15мин 15 сек

Прибавить(1час 15мин 15сек + 55 минут) => 2часа 10мин 15 сек

Создать класс массив и написать функции

Разность

Сумма

Состав отчета:

Тексты заданий

Текст программ

Приложения

‘=================

‘CLASS Man

Public name As String

Private age As Integer

Dim phone As String

Function Show() As String

Show = name & vbNewLine & "age = " & age & vbNewLine & "phone = " & phone

End Function

‘=================

‘CLASS Student

' Класс Student является агрегатом

Public m As New Man

Public group As String

Function Man\_Show() As String

Man\_Show = m.Show & vbNewLine & group

End Function

‘=================

‘ Test

Type Man1

name As String

End Type

Option Explicit

Sub test()

Dim st As Student, m As Man, m1 As Man1

'В отличие от записей, объект надо создать при помощи команды New

'Сравним m - ссылка ( указатель ) на объект типа Man

'и m1 - переменная типа Man1

m1.name = "Vasya" ' верно

' m.name = "Petya" неверно

Set m = New Man

Set st = New Student

' Обратите внимание, m и st.m - не одно и то же.

' Отдельно создан объект m типа man, и отдельно создан объект st, и в нем, в свою очередь,

' как часть его, создается объект m. Таким образом, можно говорить об объекте m и объекте st.m

m.name = "Ksenia" ' Можно, объект создан и поле name объявлено Public

' m.age = 17 Нельзя, поле недоступно, так как объявлено PRIVATE

' m.phone = "11-222" Нельзя, поле недоступно, так как объявлено DIM

st.m.name = m.name

st.group = "e-105"

MsgBox m.Show()

MsgBox st.Man\_Show()

End Sub

‘=================

‘Class Vector

Dim x\_beg As Long

Dim y\_beg As Long

Dim x\_end As Long

Dim y\_end As Long

'При написании New автоматически выполняется процедура CLASS\_INITIALIZE

Private Sub class\_initialize()

x\_beg = 0

y\_beg = 0

x\_end = 0

y\_end = 0

End Sub

Public Function length() As Variant

length = Math.Sqr((x\_beg - x\_end) ^ 2 + (y\_beg - y\_end) ^ 2)

End Function

Public Property Get xb() As Variant

xb = x\_beg

End Property

Public Property Let xb(ByVal vNewValue As Variant)

x\_beg = vNewValue

End Property

Private Property Get yb() As Variant

yb = y\_beg

End Property

Public Property Let yb(ByVal vNewValue As Variant)

y\_beg = vNewValue

End Property

Private Property Get xe() As Variant

xe = x\_end

End Property

Private Property Let xe(ByVal vNewValue As Variant)

x\_end = vNewValue

End Property

Private Property Get ye() As Variant

ye = y\_end

End Property

Private Property Let ye(ByVal vNewValue As Variant)

y\_end = vNewValue

End Property

Public Function ToString() As String

ToString = "Двумерный вектор " & \_

"(" & x\_beg & "," & y\_beg & ")" & \_

"- (" & x\_beg & "," & y\_beg & ")" & vbNewLine & \_

"Длина = " & length()

End Function

‘Class Vector3

Implements vector

Dim z\_beg As Long

Dim z\_end As Long

Private Sub class\_initialize()

x\_beg = 0

x\_end = 0

y\_beg = 0

y\_end = 0

z\_beg = 1

z\_end = 1

End Sub

Public Property Get vector\_xb() As Variant

xb = x\_beg

End Property

Public Property Let vector\_xb(ByVal vNewValue As Variant)

x\_beg = vNewValue

End Property

Public Property Let vector\_yb(ByVal vNewValue As Variant)

y\_beg = vNewValue

End Property

Public Function vector\_length() As Variant

length = Math.Sqr((x\_beg - x\_end) ^ 2 + (y\_beg - y\_end) ^ 2 + (z\_beg - z\_end) ^ 2)

End Function

Public Function vector\_ToString() As String

vector\_ToString = "Трехмерный вектор " & \_

"(" & x\_beg & "," & y\_beg & "," & z\_beg & ")" & \_

"- (" & x\_end & "," & y\_end & "," & z\_end & " )" & vbNewLine & \_

"Длина = " & vector\_length()

End Function

Sub test()

Set v = New vector 'Вектор на плоскости

Set v3 = New vector3 'Вектор в пространстве

' Функция length полиморфна, одно и то же название означает разное поведение

' Собака чует кошку и собака чует пищу (пример Патрика Ноутона, руководителя проекта "Java").

'Обычно объявляют поля объекта Private и обращаются к ним при помощи методов

'Let и Get. Никаким другим способом нельзя получить доступ к PRIVATE-переменным извне, например, нельзя завести машину, вращая дворники.

'Методы (функции) самого объекта имеют доступ ко всем переменным этого объекта

v.xb = 1

v3.vector\_xb = 1

' Или можно так

With v

.yb = 1

End With

' v.xe = 4 свойство для получения x\_end объявлено PRIVATE

MsgBox v.ToString

MsgBox v3.vector\_ToString

End Sub

‘=================

‘ CLASS Animal

Dim Name As String

Public Function toString() As String

End Function

‘==================

‘ CLASS Cat

Implements Animal

Public Function animal\_toString() As String

animal\_toString = "mew-mew"

End Function

‘==================

‘ CLASS Dog

Implements Animal

Function animal\_toString() As String

animal\_toString = "gau-gau"

End Function

‘==================

‘ CLASS Donkey

Implements Animal

Function animal\_toString() As String

animal\_toString = "ia-ia"

End Function

Attribute VB\_Name = "Zoo"

Option Explicit

Const n As Integer = 10

‘==================

Sub test()

Dim i As Integer, arr(1 To n) As Animal

Dim answer As String

' Мы заранее не знаем, какого типа зверь следующий, однако,

' благодаря полиморфизму, голос он подает правильно.

' Обратим внимание на то, что массив arr объявлен как массив ссылок на Animals

For i = 1 To n

If i Mod 3 = 0 Then

Set arr(i) = New Cat

ElseIf i Mod 3 = 1 Then

Set arr(i) = New Dog

Else

Set arr(i) = New Donkey

End If

Next

' Поскольку Кот, Собака, Ослик исполняют интерфейс животного,

' каждый объект типа ( или класса ) Кот, Собака, Ослик ... является также

' объектом типа Животное

' Это позволяет функции Голос\_Зоопарка не знать конкретный тип Кот, Пес, Ослик.

' Она работает с типом Животное. Программа становится более универсальной

' Если потребуется добавить, скажем, Слоненка (Elephant) к нашему Зоопарку,

' достаточно создать новый модуль класса Elephant по образцу Cat, Dog, Donkey,

' и в цикле создания объектов добавить новую строчку.

MsgBox Voice\_Of\_Zoo(arr)

End Sub

Function Voice\_Of\_Zoo(ByRef arr\_zoo() As Animal) As String

Dim answer As String, elem As Variant

answer = "At The Zoo" & vbNewLine & "================= " & vbNewLine

' А это мы не проходили :)

For Each elem In arr\_zoo

answer = answer & elem.toString() & vbNewLine

Next

' Можно было писать

' For i = LBound(arr\_zoo) To UBound(arr\_zoo)

' answer = answer & arr(i).toString() & vbNewLine

' Next

'

Voice\_Of\_Zoo = answer

End Function

# Контрольная работа

1. Найти наибольшее из 4х чисел.
2. Найти наименьшее из 5 чисел
3. Существует ли треугольник с заданными сторонами? Если «да», то является ли он равносторонним, равнобедренным или разносторонним?
4. Отверстие в стене имеет форму прямоугольного параллелепипеда, такова же форма кирпича. Пролезет ли кирпич в отверстие, если допускается просовывать его только параллельно стенкам отверстия?
5. Дата задается тремя числами: г, м, д. Определить дату следующего дня.
6. Время задано тремя числами: час, минута, секунда. Вводится время старта и время финиша лыжника. Сколько времени лыжник был на трассе? Ответ представить в виде: «ч:м:с»
7. Каждая клетка шахматной доски задается двузначным числом: слева направо и сверху вниз
   * 11,12,13,14,15,16,17,18,
   * 21,22,23,24,25,26,27,28,
   * 31,32,33,34,35,36,37,38,
   * 41,42,43,44,45,46,47,48,
   * 51,52,53,54,55,56,57,58,
   * 61,62,63,64,65,66,67,68,
   * 71,72,73,74,75,76,77,78,
   * 81,82,83,84,85,86,87,88,

Задаются две клетки. Лежат ли они на одной горизонтали?

1. Лежат ли они на одной вертикали?
2. Лежат ли они на одной диагонали?
3. Заданы координаты трех точек на плоскости. Найти кратчайшее расстояние до начала координат
4. Число делится на 3, если сумма его цифр делится на 3. Выяснить для трехзначного числа, делится ли оно на 3.
5. Является ли заданное четырехзначное число палиндромом (перевертышем)?
6. Автобусный билет нумеруется от 000001 до 999999. Билет считается «счастливым», если сумма первых трех цифр равна сумме последних трех цифр. Проверить, является ли билет «счастливым».
7. Задано число от 1 до 99. Записать прописью.
8. Найти 1+2+3+..+n. Цикл For
9. Найти 1+2+3+..+n. Цикл Do While
10. Найти 1+3+5+..+n, если n – нечетное, или 1+3+5+..+(n-1), если n - четное. Цикл Do While
11. Найти n! Цикл For
12. Найти n! Цикл Do While
13. Найти произведение чисел 1\*3\*5\*...\*(n-1), если n - четное и произведение чисел 1\*3\*5\*...\*n, если n – нечетное
14. Вводятся n чисел. Найти сумму четных положительных чисел. Цикл For
15. Вводятся n чисел. Найти сумму четных положительных чисел. Цикл Do While
16. Сколько всего «счастливых» билетов?
17. Найти произведение чисел 1\*3\*5\*…\*n, если n – нечетное, и 1\*3\*5\*…\*(n-1), если n - четное
18. Вводятся несколько чисел. Окончание ввода – число 0. Найти сумму.
19. Вводятся сведения об n сотрудниках:
    1. Фамилия
    2. Имя
    3. Часы
    4. Оклад

Напечатать таблицу:

N Фамилия Имя Часы Оклад Зарплата

1 Иванов Иван 20 100 2000

2 Петров Петр 30 200 6000

…………….

Итого 8000

1. Вводятся сведения о поставщиках канцтоваров:
   1. Название
   2. Цена
   3. Количество

Напечатать таблицу:

N Товар Цена Количество Сумма

1 Ручка 10 100 1000

2 Карандаш 5 200 1000

…………….

Итого 2000

1. Вводятся сведения о стоимости n автомобилей
   1. Марка
   2. Цена

Напечатать таблицу сведения о самом дорогом автомобиле, например,

Хонда – 10000$